      SUBROUTINE READ_SSMI_L1A_FILE(ILU)

      IMPLICIT NONE

C     ===================================================================================
C     =========================== BEGIN COMMON /LIA_SSMI/  ============================== 
C     ===================================================================================

      INTEGER(4) KSAT,IORBIT,NUMSCAN 
      CHARACTER(24) BTIME(1700)
      INTEGER(1) IFLAGS(12,1700),ISUR(128,2,1700),IICE(128,2,1700)
      REAL(4) FRCREV(1700),SCLAT(1700),SCLON(1700),SCALT(1700)
      REAL(4) XLAT(128,2,1700), XLON(128,2,1700), THT(128,1700), AZIMUTH(128,1700), SUNANG(128,1700)
      REAL(4) TA_LO(5,64,1700),TA_HI(6:7,128,2,1700)

      COMMON/L1A_SSMI/ KSAT,IORBIT,NUMSCAN,BTIME,IFLAGS,FRCREV,SCLAT,SCLON,SCALT,
     &                 XLAT,XLON,ISUR,IICE,THT,AZIMUTH,SUNANG,TA_LO,TA_HI

C     ===================================================================================
C     ===========================  END  COMMON /LIA_SSMI/  ============================== 
C     ===================================================================================

      CHARACTER(1) ABLANK(3756)
      CHARACTER(24) ZTIME
      INTEGER(1) ZFLAGS(12),ZTOIL(128,2)
      INTEGER(4) ILU,I,ISCAN,ZFRCREV,ZSCLAT,ZSCLON,ZSCALT
      INTEGER(2) ZLAT(128,2), ZLON(128,2), ZTHT(128), ZAZIMUTH(128), ZSUNANG(128), ZTA_LO(5,64),ZTA_HI(6:7,128,2)

      READ(ILU) KSAT,IORBIT,NUMSCAN,ABLANK
	IF(NUMSCAN.GT.1700) STOP 'TOO MANY SCANS, PROGRAM STOPPED' !THIS SHOULD NEVER HAPPEN

      DO I=1,NUMSCAN
      READ(ILU) ISCAN,ZTIME,ZFLAGS,ZFRCREV,ZSCLAT,ZSCLON,ZSCALT,ZLAT,ZLON,ZTOIL,ZTHT,ZAZIMUTH,ZSUNANG,ZTA_LO,ZTA_HI 

      IF(I.NE.ISCAN) STOP 'PGM STOPPED, ISCAN OUT OF SYNC' !THIS SHOULD NEVER HAPPEN

	BTIME(I)=ZTIME							 ! SCAN TIME
	IFLAGS(:,I)=ZFLAGS						 ! QUALITY FLAGS

      IF(ZFLAGS(1).EQ.1) THEN !MISSING SCAN
      FRCREV(I)     =0                         ! FRACTIONAL ORBIT POSITION
      SCLAT(I)      =0                         ! SPACECRAFT LATITUDE  (DEGREES)
      SCLON(I)      =0                         ! SPACECRAFT LONGITUDE (DEGREES)
      SCALT(I)      =0                         ! SPACECRAFT ALTITUDE (KM)
      XLAT(:,:,I)   =0                         ! CELL LATITDUES (DEGREES)
      XLON(:,:,I)   =0                         ! CELL EAST LONGITUDE (DEGREES)
      IICE(:,:,I)   =0                         ! SEA-ICE FLAG
      ISUR(:,:,I)   =0                         ! OCEAN, COAST, LAND FLAG
      THT(:,I)      =0                         ! CELL INCIDENCE ANGLE (DEGREES)
      AZIMUTH(:,I)  =0                         ! CELL AZIMUTH ANGLE (DEGREES)
      SUNANG(:,I)   =0                         ! CELL SUN GLITTER ANGLE (DEGREES)
      TA_LO(:,:,I)  =0                         ! CELL ANTENNA TEMPERATURES (19V, 19H, 22V, 37V, 37H)
      TA_HI(:,:,:,I)=0                         ! CELL ANTENNA TEMPERATURES (85V, 85H)

	ELSE
      FRCREV(I)     =1.E-6*ZFRCREV             ! FRACTIONAL ORBIT POSITION
      SCLAT(I)      =1.E-3*ZSCLAT              ! SPACECRAFT LATITUDE  (DEGREES)
      SCLON(I)      =1.E-3*ZSCLON              ! SPACECRAFT LONGITUDE (DEGREES)
      SCALT(I)      =1.E-3*ZSCALT              ! SPACECRAFT ALTITUDE (KM)
      XLAT(:,:,I)   =0.01*ZLAT                 ! CELL LATITDUES (DEGREES)
      XLON(:,:,I)   =0.01*ZLON + 180.          ! CELL EAST LONGITUDE (DEGREES)
      IICE(:,:,I)   =INT(ZTOIL/4)              ! SEA-ICE FLAG
      ISUR(:,:,I)   =ZTOIL - 4*INT(ZTOIL/4)    ! OCEAN, COAST, LAND FLAG
      THT(:,I)      =2.E-3*ZTHT + 45.          ! CELL INCIDENCE ANGLE (DEGREES)
      AZIMUTH(:,I)  =0.01*ZAZIMUTH + 180.      ! CELL AZIMUTH ANGLE (DEGREES)
      SUNANG(:,I)   =0.01*ZSUNANG              ! CELL SUN GLITTER ANGLE (DEGREES)
      TA_LO(:,:,I)  =0.01*ZTA_LO               ! CELL ANTENNA TEMPERATURES (19V, 19H, 22V, 37V, 37H)
      TA_HI(:,:,:,I)=0.01*ZTA_HI               ! CELL ANTENNA TEMPERATURES (85V, 85H)
	ENDIF

	ENDDO

      RETURN
      END
